' Name        : I2CX18.pbp
' Compiler    : PICBASIC PRO Compiler 2.6
' Assembler   : PM or MPASM
' Target PIC  : PIC16F88 or similar
' Hardware    : LAB-X18 Experimenter Board
' Oscillator  : 4MHz external crystal
' Keywords    : I2CREAD, I2CWRITE, LCDOUT
' Description : PICBASIC PRO program to read and write to I2C SEEPROMs.
' Writes to the first 16 locations of an external serial EEPROM.
' Reads first 16 locations back and send to LCD repeatedly.
' Note: for SEEPROMs with byte-sized address.
'

' Define LCD registers and bits
Define LCD_DREG  PORTA
Define LCD_DBIT  0
Define LCD_RSREG PORTB
Define LCD_RSBIT 6
Define LCD_EREG  PORTB
Define LCD_EBIT  3

SDA Var PORTB.1  ' Data pin
SCL Var PORTB.4  ' Clock pin

B0  Var Byte     ' Address
B1  Var Byte     ' Data 1
B2  Var Byte     ' Data 2

   ANSEL = 0     ' PORTA is digital
   CMCON = 7     ' PORTA is digital
   Pause 100     ' Wait for LCD to start up

   For B0 = 0 To 15     ' Loop 16 times
     B1 = B0 + 100      ' B1 is data for SEEPROM
     I2CWRITE SDA, SCL, $A0, B0, [B1] ' Write each location
     Pause 10           ' Delay 10ms after each write
   Next B0

loops:
   For B0 = 0 To 15 Step 2 ' Loop 8 times
     I2CREAD SDA, SCL, $A0, B0, [B1, B2]          ' Read 2 locations in a row
     Lcdout $fe, 1, #B0, ": ", #B1, " ", #B2, " " ' Display 2 locations
     Pause 1000
   Next B0
   Goto loops

   End