' Name        : I2CX20.pbp
' Compiler    : PICBASIC PRO Compiler 2.6
' Assembler   : PM or MPASM
' Target PIC  : PIC16F690 or similar type compatible with LAB-X20 board
' Hardware    : LAB-X20 Experimenter Board
' Oscillator  : 4MHz external crystal
' Keywords    : I2CREAD, I2CWRITE, LCDOUT
' Description : PICBASIC PRO program to read and write to I2C SEEPROMs.
' Writes to the first 16 locations of an external serial EEPROM.
' Reads first 16 locations back and sends to LCD repeatedly.
' Note: for SEEPROMs with byte-sized address.
'

' Define LCD registers and bits
Define LCD_DREG  PORTC
Define LCD_DBIT  0
Define LCD_RSREG PORTC
Define LCD_RSBIT 4
Define LCD_EREG  PORTC
Define LCD_EBIT  5

SDA Var PORTB.4 ' Data pin
SCL Var PORTB.6 ' Clock pin

B0 Var Byte     ' Address
B1 Var Byte     ' Data 1
B2 Var Byte     ' Data 2

   ANSEL = %00000000    ' Set all pins digital
   ANSELH = %00000000
   Pause 100            ' Wait for LCD to start up

   For B0 = 0 To 15     ' Loop 16 times
     B1 = B0 + 100      ' B1 is data for SEEPROM
     I2CWRITE SDA, SCL, $A0, B0, [B1] ' Write each location
     Pause 10           ' Delay 10ms after each write
   Next B0

mainloop:
   For B0 = 0 To 15 Step 2  ' Loop 8 times
     I2CREAD SDA, SCL, $A0, B0, [B1, B2]          ' Read 2 locations in a row
     Lcdout $fe, 1, #B0, ": ", #B1, " ", #B2, " " ' Display 2 locations
     Pause 1000
   Next B0
   Goto mainloop

   End