ME Labs, Inc. | 1-719-520-5323 | Example Program - ADCIN8.pbp

' Name        : ADCIN8.pbp
' Compiler    : PICBASIC PRO Compiler 2.6
' Assembler   : PM or MPASM
' Target PIC  : 40-pin 16F, 18F types
' Hardware    : Lab-X1 or Lab-X2 board
' Oscillator  : 4MHz internal or external
' Keywords    : ADCIN, LCDOUT
' Description : PICBASIC PRO program to display result of 8-bit
' A/D conversion on LCD. Connect analog input to channel-0 (RA0).
'

' Define LCD registers and bits
Define  LCD_DREG  PORTD
Define  LCD_DBIT  4
Define  LCD_RSREG PORTE
Define  LCD_RSBIT 0
Define  LCD_EREG  PORTE
Define  LCD_EBIT  1

' Define ADCIN parameters
Define  ADC_BITS     8     ' Set number of bits in result
Define  ADC_CLOCK    3     ' Set clock source (3=rc)
Define  ADC_SAMPLEUS 50    ' Set sampling time in uS

adval Var byte             ' Create adval to store result

   TRISA = %11111111       ' Set PORTA to all input
   ADCON1 = %00000010      ' Set PORTA analog
   Low PORTE.2             ' LCD R/W line low (W)

   Pause 500               ' Wait .5 second

mainloop:
   ADCIN 0, adval          ' Read channel 0 to adval

   Lcdout $fe, 1           ' Clear LCD
   Lcdout "Value: ", DEC adval  ' Display the decimal value  
   Pause 100               ' Wait .1 second

   Goto mainloop           ' Do it forever

   End

           

Download the program file.