SERIN Pin,Mode,{Timeout,Label,}{[Qual...],}{Item...}

Receive one or more Items on Pin in standard asynchronous format using 8 data bits, no parity and one stop bit (8N1). SERIN is similar to the BS1 Serin command with the addition of a Timeout. Pin is automatically made an input. Pin may be a constant, 0 - 15, or a variable that contains a number 0 - 15 (e.g. B0) or a pin name (e.g. PORTA.0).

The Mode names (e.g. T2400) are defined in the file MODEDEFS.BAS. To use them, add the line:

Include "modedefs.bas"

to the top of the PICBASIC PRO™ program. BS1DEFS.BAS and BS2DEFS.BAS already includes MODEDEFS.BAS. Do not include it again if one of these files is already included. The Mode numbers may be used without including this file.

An optional Timeout and Label may be included to allow the program to continue if a character is not received within a certain amount of time. Timeout is specified in units of 1 millisecond.  If the serial input pin stays idle during the Timeout time, the program will exit the SERIN command and jump to Label.

The list of data items to be received may be preceded by one or more qualifiers enclosed within brackets. SERIN must receive these bytes in exact order before receiving the data items. If any byte received does not match the next byte in the qualifier sequence, the qualification process starts over (i.e. the next received byte is compared to the first item in the qualifier list). A Qualifier can be a constant, variable or a string constant. Each character of a string is treated as an individual qualifier.

Once the qualifiers are satisfied, SERIN begins storing data in the variables associated with each Item. If the variable name is used alone, the value of the received ASCII character is stored in the variable. If variable is preceded by a pound sign ( # ), SERIN converts a decimal value in ASCII and stores the result in that variable. All non-digits received prior to the first digit of the decimal value are ignored and discarded. The non-digit character which terminates the decimal value is also discarded.

SERIN assumes a 4MHz oscillator when generating its bit timing. To maintain the proper baud rate timing with other oscillator values, be sure to DEFINE the OSC setting to the new oscillator value.

While single-chip RS-232 level converters are common and inexpensive, the excellent I/O specifications of the PICmicro allow most applications to run without level converters. Rather, inverted input (N300..N9600) can be used is conjunction with a current limiting resistor.

SERIN 1,N2400,[“A”],B0	' Wait until the character “A” is received serially 
			on Pin1 and put next character into B0

SERIN2 DataPin{\FlowPin},Mode,{ParityLabel,} {Timeout,Label,}[Item...]

Receive one or more Items on Pin in standard asynchronous format. SERIN2 is similar to the BS2 Serin command. DataPin is automatically made an input. The optional FlowPin is automatically made an output. DataPin and FlowPin may be a constant, 0 - 15, or a variable that contains a number 0 - 15 (e.g. B0) or a pin name (e.g. PORTA.0).

The optional flow control pin, FlowPin, may be included to help keep data from overrunning the receiver. If it is used, FlowPin is automatically set to the enabled state to allow transmission of each character. This enabled state is determined by the polarity of the data specified by Mode.

Mode is used to specify the baud rate and operating parameters of the serial transfer. The low order 13 bits select the baud rate. Bit 13 selects parity or no parity. Bit 14 selects inverted or true level. Bit 15 is not used.

To receive odd parity instead of even parity, include the following DEFINE in the program:

	DEFINE SER2_ ODD 1

Some examples of Mode are: Mode = 84 (9600 baud, no parity, true), Mode = 16780 (2400 baud, no parity, inverted), Mode = 27889 (300 baud, even parity, inverted).  Appendix A shows more Mode examples.

If ParityLabel is included, this label will be jumped to if a character with bad parity is received. It should only be used if even parity is selected (bit 13 = 1).

An optional Timeout and Label may be included to allow the program to continue if a character is not received within a certain amount of time. Timeout is specified in units of 1 millisecond.  If the serial input pin stays idle during the Timeout time, the program will exit the SERIN2 command and jump to Label.

A DEFINE allows the use of data bits other than 8 (or 7 with parity). SER2_BITS data bits may range from 4 bits to 8 (the default if no DEFINE is specified). Enabling parity uses one of the number of bits specified.

	DEFINE SER2_BITS 4	' Set Serin2 and Serout2 data bits to 4
	DEFINE SER2_BITS 5	' Set Serin2 and Serout2 data bits to 5
	DEFINE SER2_BITS 6	' Set Serin2 and Serout2 data bits to 6
	DEFINE SER2_BITS 7	' Set Serin2 and Serout2 data bits to 7
	DEFINE SER2_BITS 8	' Set Serin2 and Serout2 data bits to 8 (default)

	DEFINE SER2_BITS 5	' Set Serin2 and Serout2 data bits to 4
	DEFINE SER2_BITS 6	' Set Serin2 and Serout2 data bits to 5
	DEFINE SER2_BITS 7	' Set Serin2 and Serout2 data bits to 6
	DEFINE SER2_BITS 8	' Set Serin2 and Serout2 data bits to 7 (default)
	DEFINE SER2_BITS 9	' Set Serin2 and Serout2 data bits to 8

SERIN2 supports many different data modifiers which may be mixed and matched freely within a single SERIN2 statement to provide various input formatting.

Once any WAIT or WAITSTR qualifiers are satisfied, SERIN2 begins storing data in the variables associated with each Item. If the variable name is used alone, the value of the received ASCII character is stored in the variable. If variable is preceded by BIN, DEC or HEX, then SERIN2 converts a binary, decimal or hexadecimal value in ASCII and stores the result in that variable. All non-digits received prior to the first digit of the decimal value are ignored and discarded. The non-digit character which terminates the value is also discarded.

BIN, DEC and HEX may be followed by a number. Normally, these modifiers receive as many digits as are in the input. However, if a number follows the modifier, SERIN2 will always receive that number of digits, skipping additional digits as necessary.

SERIN2 assumes a 4MHz oscillator when generating its bit timing. To maintain the proper baud rate timing with other oscillator values, be sure to DEFINE the OSC setting to the new oscillator value.

While single-chip RS-232 level converters are common and inexpensive, thanks to current RS-232 implementation and the excellent I/O specifications of the PICmicro, most applications don't require level converters. Rather, inverted TTL (Mode bit 14 = 1) can be used. A current limiting resistor is suggested (RS-232 is suppose to be short-tolerant).

	' Wait until the character “A” is received serially on Pin1 and put next character into B0
	SERIN2 1,16780,[wait (“A”),B0]

	' Skip 2 chars and grab a 4 digit decimal number
	SERIN2 PORTA.1,84,[skip 2,dec4 B0]

	SERIN2 PORTA.1\PORTA.0,84,100,tlabel,[wait (“x”, b0), str ar]

SEROUT Pin,Mode,[Item{,Item...}]

Sends one or more items to Pin in standard asynchronous format using 8 data bits, no parity and one stop (8N1). SEROUT is similar to the BS1 Serout command. Pin is automatically made an output. Pin may be a constant, 0 - 15, or a variable that contains a number 0 - 15 (e.g. B0) or a pin name (e.g. PORTA.0).

The Mode names (e.g. T2400) are defined in the file MODEDEFS.BAS. To use them, add the line:

Include "modedefs.bas"

to the top of the PICBASIC PRO™ program. BS1DEFS.BAS and BS2DEFS.BAS already includes MODEDEFS.BAS. Do not include it again if one of these files is already included. The Mode numbers may be used without including this file.

SEROUT supports three different data types which may be mixed and matched freely within a single SEROUT statement.

SEROUT assumes a 4MHz oscillator when generating its bit timing. To maintain the proper baud rate timing with other oscillator values, be sure to DEFINE the OSC setting to the new oscillator value.

In some cases, the transmission rates of SEROUT instructions may present characters too quickly to the receiving device. A DEFINE adds character pacing to the serial output transmissions. This allows additional time between the characters as they are transmitted. The character pacing DEFINE allows a delay of 1 to 65,535 microseconds (.001 to 65.535 milliseconds) between each character transmitted.

While single-chip RS-232 level converters are common and inexpensive, thanks to current RS-232 implementation and the excellent I/O specifications of the PICmicro, most applications don't require level converters. Rather, inverted TTL (N300..N9600) can be used. A current limiting resistor is suggested (RS-232 is suppose to be short-tolerant).

	SEROUT 0,N2400,[#B0,10]	' Send the ASCII value of B0 followed by 
					a linefeed out Pin0 serially

SEROUT2 DataPin{\FlowPin},Mode,{Pace,} {Timeout,Label,}[Item...]

Send one or more Items to DataPin in standard asynchronous format. SEROUT2 is similar to the BS2 Serout command. DataPin is automatically made an output. The optional FlowPin is automatically made an input. DataPin and FlowPin may be a constant, 0 - 15, or a variable that contains a number 0 - 15 (e.g. B0) or a pin name (e.g. PORTA.0).

The optional flow control pin, FlowPin, may be included to help keep data from overrunning the receiver. If it is used, the serial data will not be sent until FlowPin is in the proper state. This state is determined by the polarity of the data specified by Mode.

An optional Timeout and Label may be included to allow the program to continue if the FlowPin does not change to the enabled state within a certain amount of time. Timeout is specified in units of 1 millisecond.  If FlowPin stays disabled during the Timeout time, the program will exit the SEROUT2 command and jump to Label.

In some cases, the transmission rates of SEROUT2 instructions may present characters too quickly to the receiving device. It may not be desirable to use an extra pin for flow control. An optional Pace can be used to add character pacing to the serial output transmissions. This allows additional time between the characters as they are transmitted. The character pacing allows a delay of 1 to 65,535 milliseconds between each character transmitted.

Mode is used to specify the baud rate and operating parameters of the serial transfer. The low order 13 bits select the baud rate. Bit 13 selects parity or no parity. Bit 14 selects inverted or true level. Bit 15 selects whether it is driven or open.

Bit 13 selects even parity (bit 13 = 1) or no parity (bit 13 = 0). Normally, the serial transmissions are 8N1 (8 data bits, no parity and 1 stop bit). If parity is selected, the data is sent as 7E1 (7 data bits, even parity and 1 stop bit).  To transmit odd parity instead of even parity, include the following DEFINE in the program:

DEFINE SER2_ ODD 1

Some examples of Mode are: Mode = 84 (9600 baud, no parity, true, always driven), Mode = 16780 (2400 baud, no parity, inverted, driven), Mode = 60657 (300 baud, even parity, inverted, open).   Appendix A shows more Mode examples.

A DEFINE allows the use of data bits other than 8 (or 7 with parity). SER2_BITS data bits may range from 4 bits to 8 (the default if no DEFINE is specified). Enabling parity uses one of the number of bits specified.

	DEFINE SER2_BITS 4	' Set Serin2 and Serout2 data bits to 4
	DEFINE SER2_BITS 5	' Set Serin2 and Serout2 data bits to 5
	DEFINE SER2_BITS 6	' Set Serin2 and Serout2 data bits to 6
	DEFINE SER2_BITS 7	' Set Serin2 and Serout2 data bits to 7
	DEFINE SER2_BITS 8	' Set Serin2 and Serout2 data bits to 8 (default)

	DEFINE SER2_BITS 5	' Set Serin2 and Serout2 data bits to 4
	DEFINE SER2_BITS 6	' Set Serin2 and Serout2 data bits to 5
	DEFINE SER2_BITS 7	' Set Serin2 and Serout2 data bits to 6
	DEFINE SER2_BITS 8	' Set Serin2 and Serout2 data bits to 7 (default)
	DEFINE SER2_BITS 9	' Set Serin2 and Serout2 data bits to 8

SEROUT2 supports many different data modifiers which may be mixed and matched freely within a single SEROUT2 statement to provide various output formatting.

SEROUT2 is not supported on 12-bit core PICmicro MCUs due to RAM and stack constraints.

	' Send the ASCII value of B0 followed by a linefeed out Pin0 serially at 2400 baud 
	SEROUT2 0,16780,[dec B0,10]

	' Send “B0 =” followed by the binary value of B0 out PORTA pin 1 serially at 9600 baud 
	SEROUT2 PORTA.1,84,[“B0=”, ihex4 B0]