ME Labs, Inc. | 1-719-520-5323 | Example Program - VMETERX.pbp

' Name        : VMETERX.pbp
' Compiler    : PICBASIC PRO Compiler 2.60
' Assembler   : PM or MPASM
' Target PIC  : 40-pin 16F887 or similar
' Hardware    : LAB-X1 Experimenter Board
' Oscillator  : 4MHz external
' Keywords    : ADCIN, LCDOUT
' Description : PICBASIC PRO program to measure voltage (0-5VDC)
' and display on LCD with 2 decimal places.
' This program uses the */ operator to scale the ADC result from 0-1023
' to 0-500. The */ performs a divide by 256 automatically, allowing math
' which would normally exceed the limit of a word variable.

' Connect analog input to channel-0 (RA0)

' Define LCD registers and bits
Define LCD_DREG  PORTD
Define LCD_DBIT  4
Define LCD_RSREG PORTE
Define LCD_RSBIT 0
Define LCD_EREG  PORTE
Define LCD_EBIT  1

' Define ADCIN parameters ********************************
Define ADC_BITS     10 ' Set number of bits in result
Define ADC_SAMPLEUS 50 ' Set sampling time in uS
'Define ADC_CLOCK    3 ' This define is inoperative on 16F88x
ADCON0 = %11000000     ' Set ADC_CLOCK to RC (DEFINE ACD_CLOCK inoperative on the 16F88x)
ADCON1 = %10000000     ' Right-Justify result in ADRESH:ADRESL registers
ANSEL = %00000001      ' Set AN0-AN7 to digital with the exeption of AN0
ANSELH = %00000000     ' Set AN8 and higher channels to digital operation
'**********************************************************

adval Var Word         ' Create adval to store result

   TRISA = %11111111   ' Set PORTA to all input
   Low PORTE.2         ' LCD R/W line low (W)
   Pause 500           ' Wait .5 second

mainloop:
   Adcin 0, adval      ' Read channel 0 to adval (0-1023)
   adval = (adval */ 500)>>2 ' Equates to: (adval * 500)/1024
   Pause 100           ' Wait .1 second
   LCDOut $FE, $80, "DC Volts= ",DEC (adval/100),".", DEC2 adval ' Display the decimal value 
   Goto mainloop       ' Do it forever

   End

           

Download the program file.